mirror of
https://gitlab.com/qemu-project/openbios.git
synced 2024-02-13 08:34:06 +08:00
b26b3c4391
Signed-off-by: igor.v.kovalenko@gmail.com Signed-off-by: Blue Swirl <blauwirbel@gmail.com> git-svn-id: svn://coreboot.org/openbios/trunk/openbios-devel@562 f158a5a8-5612-0410-a976-696ce0be7e32
74 lines
1.4 KiB
Plaintext
74 lines
1.4 KiB
Plaintext
OUTPUT_FORMAT(elf64-sparc)
|
|
OUTPUT_ARCH(sparc:v9)
|
|
|
|
/* Qemu ELF loader can't handle very complex files, so we put ELFBoot
|
|
info to rodata and put initctx to data.*/
|
|
|
|
ENTRY(trap_table)
|
|
|
|
/* Initial load address
|
|
*/
|
|
BASE_ADDR = 0x00000000ffd00000;
|
|
|
|
/* 16KB stack */
|
|
STACK_SIZE = 16384;
|
|
VMEM_SIZE = 128 * 1024;
|
|
IOMEM_SIZE = 256 * 1024 + 768 * 1024;
|
|
|
|
SECTIONS
|
|
{
|
|
. = BASE_ADDR;
|
|
|
|
/* Start of the program.
|
|
* Now the version string is in the note, we must include it
|
|
* in the program. Otherwise we lose the string after relocation. */
|
|
_start = .;
|
|
|
|
/* Normal sections */
|
|
.text ALIGN(524288): {
|
|
*(.text.vectors)
|
|
*(.text)
|
|
*(.text.*)
|
|
}
|
|
.rodata ALIGN(524288): {
|
|
_rodata = .;
|
|
sound_drivers_start = .;
|
|
*(.rodata.sound_drivers)
|
|
sound_drivers_end = .;
|
|
*(.rodata)
|
|
*(.rodata.*)
|
|
*(.note.ELFBoot)
|
|
}
|
|
.data ALIGN(524288): {
|
|
_data = .;
|
|
*(.data)
|
|
*(.data.*)
|
|
}
|
|
|
|
.bss ALIGN(4096): {
|
|
_bss = .;
|
|
*(.bss)
|
|
*(.bss.*)
|
|
*(COMMON)
|
|
|
|
. = ALIGN(4096);
|
|
_vmem = .;
|
|
. += VMEM_SIZE;
|
|
_evmem = .;
|
|
|
|
_stack = .;
|
|
. += STACK_SIZE;
|
|
. = ALIGN(16);
|
|
_estack = .;
|
|
}
|
|
|
|
. = ALIGN(4096);
|
|
_end = .;
|
|
_iomem = _end + IOMEM_SIZE;
|
|
|
|
/* We discard .note sections other than .note.ELFBoot,
|
|
* because some versions of GCC generates useless ones. */
|
|
|
|
/DISCARD/ : { *(.comment*) *(.note.*) }
|
|
}
|