mirror of
https://github.com/intel/llvm.git
synced 2026-01-22 15:41:35 +08:00
d3199f5ed2
Summary: This patch adds a CMake option LLDB_BUILD_FRAMEWORK, which builds libLLDB as a macOS framework instead of as a *nix shared library. With this patch any LLDB executable that has the INCLUDE_IN_FRAMEWORK option set will be built into the Framework's resources directory, and a symlink to the exeuctable will be placed under the build directory's bin folder. Creating the symlinks allows users to run commands from the build directory without altering the workflow. The framework generated by this patch passes the LLDB test suite, but has not been tested beyond that. It is not expected to be fully ready to ship, but it is a first step. With this patch binaries that are placed inside the framework aren't being properly installed. Fixing that would increase the patch size significantly, so I'd like to do that in a follow-up. Reviewers: zturner, tfiala Subscribers: beanz, lldb-commits, mgorny Differential Revision: https://reviews.llvm.org/D24749 llvm-svn: 282110
57 lines
2.2 KiB
CMake
57 lines
2.2 KiB
CMake
file(GLOB SWIG_INTERFACES interface/*.i)
|
|
file(GLOB_RECURSE SWIG_SOURCES *.swig)
|
|
set(SWIG_HEADERS
|
|
${LLDB_SOURCE_DIR}/include/lldb/API/SBDefines.h
|
|
${LLDB_SOURCE_DIR}/include/lldb/lldb-defines.h
|
|
${LLDB_SOURCE_DIR}/include/lldb/lldb-enumerations.h
|
|
${LLDB_SOURCE_DIR}/include/lldb/lldb-forward.h
|
|
${LLDB_SOURCE_DIR}/include/lldb/lldb-types.h
|
|
${LLDB_SOURCE_DIR}/include/lldb/lldb-versioning.h
|
|
)
|
|
|
|
include(FindPythonInterp)
|
|
|
|
set(SWIG_PYTHON_DIR
|
|
${CMAKE_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX}/python${PYTHON_VERSION_MAJOR}.${PYTHON_VERSION_MINOR})
|
|
set(SWIG_INSTALL_DIR lib${LLVM_LIBDIR_SUFFIX})
|
|
|
|
# Generating the LLDB framework correctly is a bit complicated because the
|
|
# framework depends on the swig output.
|
|
if(LLDB_BUILD_FRAMEWORK)
|
|
set(framework_arg --framework --target-platform Darwin)
|
|
set(SWIG_PYTHON_DIR
|
|
${LLDB_PYTHON_TARGET_DIR}/${LLDB_FRAMEWORK_RESOURCE_DIR}/Python)
|
|
set(SWIG_INSTALL_DIR
|
|
${LLDB_FRAMEWORK_INSTALL_DIR}/${LLDB_FRAMEWORK_RESOURCE_DIR})
|
|
endif()
|
|
|
|
find_package(SWIG REQUIRED)
|
|
add_custom_command(
|
|
OUTPUT ${LLDB_WRAP_PYTHON}
|
|
OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/lldb.py
|
|
DEPENDS ${SWIG_SOURCES}
|
|
DEPENDS ${SWIG_INTERFACES}
|
|
DEPENDS ${SWIG_HEADERS}
|
|
DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/Python/prepare_binding_Python.py
|
|
DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/Python/modify-python-lldb.py
|
|
COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/prepare_bindings.py
|
|
${framework_arg}
|
|
"--srcRoot=${LLDB_SOURCE_DIR}"
|
|
"--targetDir=${LLDB_PYTHON_TARGET_DIR}"
|
|
"--cfgBldDir=${CMAKE_CURRENT_BINARY_DIR}"
|
|
"--prefix=${CMAKE_BINARY_DIR}"
|
|
"--swigExecutable=${SWIG_EXECUTABLE}"
|
|
COMMENT "Python script building LLDB Python wrapper")
|
|
set_source_files_properties(${LLDB_WRAP_PYTHON} PROPERTIES GENERATED 1)
|
|
set_source_files_properties(${CMAKE_CURRENT_BINARY_DIR}/lldb.py PROPERTIES GENERATED 1)
|
|
|
|
add_custom_target(swig_wrapper ALL DEPENDS ${LLDB_WRAP_PYTHON})
|
|
|
|
# Install the LLDB python module on all operating systems (except Windows)
|
|
if (NOT CMAKE_SYSTEM_NAME MATCHES "Windows")
|
|
install(DIRECTORY ${SWIG_PYTHON_DIR} DESTINATION ${SWIG_INSTALL_DIR})
|
|
endif()
|
|
|
|
# build Python modules
|
|
add_subdirectory(Python/modules)
|