mirror of
https://github.com/intel/llvm.git
synced 2026-01-19 09:31:59 +08:00
f4f8a67aaf
* Makes `pip install pybind11` do the right thing with no further config. * Since we now require a version of pybind11 greater than many LTS OS installs (>=2.6), a more convenient way to get a recent version is preferable. * Also adds the version spec to find_package so it will skip older versions that may be lying around. * Tested the full matrix of old system install, no system install, pip install and no pip install. Differential Revision: https://reviews.llvm.org/D91903
27 lines
1.1 KiB
CMake
27 lines
1.1 KiB
CMake
# Macros and functions related to detecting details of the Python environment.
|
|
|
|
# Detects a pybind11 package installed in the current python environment
|
|
# and sets variables to allow it to be found. This allows pybind11 to be
|
|
# installed via pip, which typically yields a much more recent version than
|
|
# the OS install, which will be available otherwise.
|
|
function(mlir_detect_pybind11_install)
|
|
if(pybind11_DIR)
|
|
message(STATUS "Using explicit pybind11 cmake directory: ${pybind11_DIR} (-Dpybind11_DIR to change)")
|
|
else()
|
|
message(CHECK_START "Checking for pybind11 in python path...")
|
|
execute_process(
|
|
COMMAND "${PYTHON_EXECUTABLE}"
|
|
-c "import pybind11;print(pybind11.get_cmake_dir(), end='')"
|
|
WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
|
|
RESULT_VARIABLE STATUS
|
|
OUTPUT_VARIABLE PACKAGE_DIR
|
|
ERROR_QUIET)
|
|
if(NOT STATUS EQUAL "0")
|
|
message(CHECK_FAIL "not found (install via 'pip install pybind11' or set pybind11_DIR)")
|
|
return()
|
|
endif()
|
|
message(CHECK_PASS "found (${PACKAGE_DIR})")
|
|
set(pybind11_DIR "${PACKAGE_DIR}" PARENT_SCOPE)
|
|
endif()
|
|
endfunction()
|